packer.cljs

(ns ulysses.lib.packer
  (:require [clojure.walk :refer [keywordize-keys]]
            [ulysses.utils :refer [map-subels ptr]]
            [ulysses.extra :refer [Packer textDimensions]]))

(defn fit
  [w h blocks]
  (let [p (new Packer w h)]
    (->> blocks
         (sort-by :h)
         (reverse)
         (clj->js)
         (.fit p)
         (js->clj)
         (keywordize-keys)
         (map
           (fn [block]
             (update block :fit dissoc
               :used :right :down :w :h))))))

(defn text-dimensions
  [text options]
  (-> text
      (textDimensions (clj->js options))
      (js->clj)
      (keywordize-keys)))

(defn fit-words
  [w h words]
  (let [style-base {:fontFamily "Source Sans Pro" :fontWeight "100"}]
    [:div
      {:style {:position :relative :width w :height h}}
      (->> words
           (map
             (fn [{:keys [name weight]}]
               (let [style (assoc style-base :fontSize (-> weight (* 10) (Math/log) (* 35) (str "px")))]
                 (-> name
                     (text-dimensions style)
                     (update :w
                      (partial + 8))
                     (assoc :style style)
                     (assoc :weight weight)))))
           (fit w h)
           (map-subels
            (fn [{:keys [w h fit name style weight]}]
              [:a.keyword
                {:style
                 (assoc style
                  :width w
                  :height h
                  :left (:x fit)
                  :top (:y fit))
                 :class
                 (str "weight-" (Math/round (* 100 weight)))}
                name])))]))