RangeApp.pde

Camera cam;
TreeContainer pot;//or tree
Menu menu;
Selector selector;
Point nearestNeighbor;
ArrayList<Point> pointList, selectedList;
boolean drawCon, drawHelp, drawTreeRelations, drawTreeBoundaries, drawGnoman, useSelector;

void setup() {
  size(800,800);
  background(120);
  ellipseMode(CENTER);
  cam = new Camera();
  pot = new TreeContainer();
  selector = new Selector();
  nearestNeighbor = null;
  menu = new Menu();
  pointList = new ArrayList<Point>();
  selectedList = new ArrayList<Point>();

  drawCon = false;
  drawHelp = false;
  drawGnoman = true;
  drawTreeRelations = false;
  drawTreeBoundaries = true;
  
}

void draw() {
  background(c_background);
  
  pushMatrix();
    cam.update();
    if(drawGnoman) GnomanDraw(200);
    
    if(drawTreeBoundaries) {
      pot.drawBoundaries();
    }
   
    if(drawTreeRelations) {
      pot.drawRelations();
    }
  
    for(Point p: pointList) {
      p.draw();
    }
  popMatrix();

  if(useSelector) {
    selector.draw();
  }

  if (drawHelp) {
    drawHelpMenu();
  } else {
    menu.draw();
  }

}

void keyPressed() {
  switch(key) {
    case 'c':
    case 'C':
      pointList.clear();
      selectedList.clear();
      pot.clearTree();
      break;
    case 'h':
    case 'H':
      drawHelp = !drawHelp;
      break;
    case 'k':
    case 'K':
      drawTreeRelations = !drawTreeRelations;
      break;
    case 'j':
    case 'J':
      drawTreeBoundaries = !drawTreeBoundaries;
      break;
    case 'e':
    case 'E':
      drawGnoman = !drawGnoman;
      break;
    case 'r':
    case 'R':
      addRandom(1);
      break;
    case 't':
    case 'T':
      addRandom(20);
      break;
  } 
}

void checkSelect() {}

void setSelected(ArrayList<Point> pointList) {
  for(Point p: selectedList) {
    p.setUnSelected();
  }
  selectedList = pointList;
  for(Point p: selectedList) {
    p.setSelected();
  }
}

void addRandom(int n) {
  for(int i = 0; i < n; i++) {
     Point p = new Point((int)random(width),(int)random(height));
     Point r = cam.transform(p);
     pointList.add(r);
     pot.insert(r);
  }
}

void GnomanDraw(int r) {
  pushStyle();
  stroke(c_gnoman);
  line(-r,0,r,0);
  line(0,-r,0,r);
  popStyle();
}

void mousePressed() {
  if(mouseButton == LEFT && !menu.mousePressed()) { 
    if(useSelector) {
      selector.mousePressed(); 
    } else {
      cam.mousePressed();
    }
  }
  if(mouseButton == RIGHT) { 
    cam.mousePressed();
  }
}

void mouseDragged() {
  if(mouseButton == LEFT) { 
    if(useSelector) {
      selector.mouseDragged();
    } else {
      cam.mouseDragged();
    }
  }
  if(mouseButton == RIGHT) { 
    cam.mouseDragged(); 
  }
}

void mouseReleased() {
  if(mouseButton == LEFT) { 
    if(useSelector) {
      menu.mouseReleased(); 
    } else {
      cam.mouseReleased();
    }
  }
  if(mouseButton == RIGHT) { 
    cam.mouseReleased(); 
  }
}

void balanceTree (ArrayList<Point> points, boolean dir) {

}